Run the "RunReports.bat" in the project folder.
The Desktop reports are not run automatically on Accelerator, if you want to see these reports, you need to run the "RunReports.bat"- file in the root of your project folder.
It is located in the project directory, double click it.
You will likely get a warning:
Click 'Run anyway', it will the run the reports executable and produce the results.
If you want to be sure what it does you can open the shell script in a notebook.@echo off
rem --------------------------------------------------------------------
rem --------------------------------------------------------------------
rem ----- The user could set the paths here ---------------------------
set Project=NULL
set Version=NULL
set Layout=NULL
set WindSimFolder=NULL
set Environment=NULL
rem ----- otherwise we try to detect it automatically -----------
rem --------------------------------------------------------------------
rem detects .ws in current folder
IF %Project% == NULL (
for %%i in (*.ws) do set Project=%%i
)
set Project= %cd%\%Project%
echo ---------------------
echo We are going to create the Windfields reports with the following parameters:
echo Project: %Project:~1%
rem read the Project file and get Version
IF %Version% == NULL (
set "Version="
for /f "tokens=3 delims=<>" %%a in (
'find /i "<Version>" ^< "%Project:~1%"'
) do set "Version=%%a"
)
echo Version: %Version%
rem read the LayoutList and get Name, layout name
IF %Layout% == NULL (
set "Layout="
for /f "tokens=3 delims=<>" %%a in (
'find /i "<Name>" ^< "LayoutList.xml"'
) do set "Layout=%%a"
)
echo Layout: %Layout%
IF %Environment% == NULL (
set Environment=%appdata%\WindSim\%Version%\Environment.xml
)
echo Environment: %Environment%
rem WindSimFolder read from the Environment.xml
IF %WindSimFolder% == NULL (
set "WindSimFolder="
for /f "tokens=3 delims=<>" %%a in (
'find /i "<WindSimFolder>" ^< "%Environment%"'
) do set "WindSimFolder=%%a"
)
echo Program folder: %WindSimFolder%\bin\
echo ---------------------
rem Read sectors from Project file
SETLOCAL ENABLEDELAYEDEXPANSION
start /wait /B "" "%WindSimFolder%\bin\Reports.exe" "%Project:~1%" "%Layout%.lws" "%Environment%" "1"
for /f "tokens=3 delims=<>" %%a in (
'find /i "<Sector>" ^< "%Project:~1%"'
) do (
set /a "sector+=1"
echo start sector !sector! : %%a degrees
start /wait /B "" "%WindSimFolder%\bin\Reports.exe" "%Project:~1%" "%Layout%.lws" "%Environment%" "2" "/si!sector!"
echo ---------------------
)
PAUSE